import org.springframework.boot.gradle.plugin.SpringBootPlugin

plugins {
    id 'org.springframework.boot' version '3.2.3' apply false
    id 'java-platform'
    id 'halo.publish'
    id 'signing'
}

group = 'run.halo.tools.platform'
description = 'Platform of application.'

ext {
    commonsLang3 = "3.12.0"
    base62 = "0.1.3"
    pf4j = '3.11.0'
    javaDiffUtils = "4.12"
    guava = "32.0.1-jre"
    jsoup = '1.15.3'
    jsonPatch = "1.13"
    springDocOpenAPI = "2.3.0"
    lucene = "9.9.1"
    resilience4jVersion = "2.2.0"
    twoFactorAuth = "1.3"
}

javaPlatform {
    allowDependencies()
}

dependencies {
    api platform(SpringBootPlugin.BOM_COORDINATES)

    constraints {
        api "org.springdoc:springdoc-openapi-starter-webflux-ui:$springDocOpenAPI"
        api 'org.openapi4j:openapi-schema-validator:1.0.7'

        // Apache Lucene
        api "org.apache.lucene:lucene-core:$lucene"
        api "org.apache.lucene:lucene-queryparser:$lucene"
        api "org.apache.lucene:lucene-highlighter:$lucene"
        api "org.apache.lucene:lucene-backward-codecs:$lucene"
        api "org.apache.lucene:lucene-analysis-common:$lucene"

        api "org.apache.commons:commons-lang3:$commonsLang3"
        api "io.seruco.encoding:base62:$base62"
        api "org.pf4j:pf4j:$pf4j"
        api "com.google.guava:guava:$guava"
        api "org.jsoup:jsoup:$jsoup"
        api "io.github.java-diff-utils:java-diff-utils:$javaDiffUtils"
        api "org.springframework.integration:spring-integration-core"
        api "com.github.java-json-tools:json-patch:$jsonPatch"
        api "org.thymeleaf.extras:thymeleaf-extras-springsecurity6"
        api "io.github.resilience4j:resilience4j-spring-boot3:$resilience4jVersion"
        api "io.github.resilience4j:resilience4j-reactor:$resilience4jVersion"
        api "com.j256.two-factor-auth:two-factor-auth:$twoFactorAuth"

        runtime 'org.mariadb:r2dbc-mariadb:1.1.4'
    }

}